; JesseR's version of the mIRC Webster dictionary (v2.0)
; various other versions were written by various other people. i based this on mexis's.

; /define word - looks up the word/phrase in the Webster database (spaces ok)
;
; If the word is misspelled, the server will give you a list of corrections.
; You can then /define correctspelling OR /define number (use the number from the list).
;
; You can use ? and * wildcards to search for words or phrases you can't spell.
; (? = any one letter, * = anything or nothing)
;
; btw, you can send a "help" command for technical stuff: /dictionary help

alias define {
  echo 4 -s Looking up: $chr(2) $+ $chr(31) $+ $1-
  set %dictbold $true
  dictionary DEFINE $1-
}

alias dictionary {
  if ($sock(Dictionary) == Dictionary) { 
    ; already connected to dictionary server
    sockwrite -n Dictionary $upper($1-)
  }
  else { 
    set %dictcommand $upper($1-)
    sockopen Dictionary muesli.ai.mit.edu 2627 
  }
}

on 1:sockopen:Dictionary:{
  if ( $sockerr != 0 ) { echo 4 -s Failed to connect to dictionary server: cryptic error number $sockerr }
  else { sockwrite -n Dictionary %dictcommand }

  unset %dictcommand
}

on 1:sockread:Dictionary:{
  sockread %temp

  ; webster server sends character 128 (EOF?) at the end of each /define, but mirc
  ; thinks it comes at the beginning of the next reply.
  set %temp $remove(%temp,$chr(128))

  ; sometimes the server will send a blank line, so make it show a blank line and not an error
  if ( %temp == $null ) { echo 5 -s $chr(160) | halt }

  ; bold the first line returned after i type /define something
  if ( %dictbold == $true ) { set %temp $chr(2) $+ %temp | unset %dictbold }

  echo 5 -s %temp  
}

alias easc for 1 $len($$1) echo -s $!1 $!asc($!mid( $1 ,$!1,1))